/*
cd "C:\Users\chkim\OneDrive - The University of Kansas\Lectures\Soc910_AdvStat\examples"

use soc910_1_data1.dta, clear

* sample limitation

keep if relate==1 | relate==2 
keep if age>=25 & age<=54
gen married=marst==1
drop if (age_sp<25 | age_sp>54) & married==1

sort serial
by serial: egen nadult = count(serial)
keep if nadult==1 | nadult==2

keep if age>=35 & age<=44

save, replace
*/

cd "C:\Users\sovid\OneDrive - The University of Kansas\Lectures\Soc910_AdvStat\examples"

use soc910_data_1.dta, clear

* Recode
numlabel, add

gen     emp = 1 if empstat==1
replace emp = 0 if empstat==2

gen female=sex==2
gen single=marst==6
gen married = marst==1

gen     races=5
replace races=1 if raced==100 & hispan==0
replace races=2 if raced==200 & hispan==0 
replace races=4 if raced>=400 & raced<=679 & hispan==0

gen minority = races!=1

gen     edu=1
replace edu=2 if educd==63 | educd==64
replace edu=3 if educd>=65 & educd<=100
replace edu=4 if educd==101
replace edu=5 if educd==114
replace edu=6 if educd==115
replace edu=7 if educd==116

replace edu=5 if edu>=5

gen ba = edu>=5

gen profmanag= occ1990 <=200

gen age2=age*age
gen immig=yrimmig!=0


* Logistic regression with interaction

logit profmanag minority female ba age age2 [pw=perwt]
logit profmanag i.minority##i.female ba age age2 [pw=perwt]
logit profmanag i.minority##i.ba female age age2 [pw=perwt]

margins minority#ba
mlincom (4-2)
mlincom (4-2)-(3-1)

margins minority#ba
marginsplot

margins, dydx(minority) at(age=(35(1)44))
marginsplot, yline(0)


* Multinomial Logit

mlogit empstat i.edu i.female i.minority age age2 [pw=perwt]
margins edu, atmeans 

margins edu, predict() over(i.female) atmeans 
margins i.edu, dydx(i.female) atmeans

gen unemp = empstat==2
logit unemp i.edu female minority age age2 [pw=perwt] if empstat==1 | empstat==2

mlogit empstat i.edu female minority age age2 [pw=perwt], baseoutcome(2)



* ordered logit

use "soc910_data_EASS2012.dta", clear

gen     yrsch = educyrs
replace yrsch = 6 if educyrs==88 & degree==1
replace yrsch = 9 if educyrs==88 & degree==2
replace yrsch = 11 if educyrs==88 & degree==3
replace yrsch = 14 if educyrs==88 & degree==4
replace yrsch = 16 if educyrs==88 & degree==5
replace yrsch = 18 if educyrs==88 & degree==6
replace yrsch = 10 if educyrs==88 & degree==8

ologit SWB SSS c.age##c.age female yrsch [pw=weight]
margins
margins, at(SSS=(1(3)10))